دانلود اسکریپت خروجی لیست معاملات به صورت اکسل CSV

دسامبر 13th, 2021 اسکریپت ام کیو ال و اتو تریدینگ

5 / 0

به این مقاله امتیاز دهید.

دانلود اسکریپت خروجی لیست معاملات برای متاتریدر 5 فایل خروجی در پوشته \MQL5\Files قرار میگیرد لیست خروجی به شرح زیر خواهد بود : Position ID Type Symbol Volume Open Date/Time Open Price Close Date/Time Close Price TakeProfit, data not available using HistoryOrderGetDouble(order_ticket, ORDER_TP) StopLoss, data not available using HistoryOrderGetDouble(order_ticket, ORDER_SL) Position PnL Position PnL (points) […]

توضیحات دانــــلود دیدگاه ها

دانلود اسکریپت خروجی لیست معاملات برای متاتریدر 5
فایل خروجی در پوشته \MQL5\Files قرار میگیرد
لیست خروجی به شرح زیر خواهد بود :

Position ID
Type
Symbol
Volume
Open Date/Time
Open Price
Close Date/Time
Close Price
TakeProfit, data not available using HistoryOrderGetDouble(order_ticket, ORDER_TP)
StopLoss, data not available using HistoryOrderGetDouble(order_ticket, ORDER_SL)
Position PnL
Position PnL (points)
Swap
Swap (points)
Commission
Commission (points)
Total PnL
Total PnL (points)
MagicNumber
Comment, this includes the comment of each deal separated by /
Deal in ID, this includes the ticket of the in deal
Deal out ID, this includes the ticket of each out deals

برچسب‌ها :

اسکریپت لیست معاملات متاتریدر هیستوری

مقالات مرتبط

دسامبر 7th, 2023 بایگانی‌ها

5 / 0

Amka Ccf دانلود و معرفی اندیکاتور

معرفی و دانلود اندیکاتور کاربردی Amka Ccf اندیکاتور کاربردی Amka Ccf روند ترکیبی از چندین اندیکاتور شناخته شده است که داده ها را به صورت متوالی با سیگنال دادن به تغییر روند پردازش می کند. معرفی اندیکاتور کاربردی Amka Ccf اندیکاتوری کاربردی با قابلیت صدور هشدار و آلارم به صورت فایل صوتی ، ارسال ایمیل […]

0 ادامه مقاله

نوامبر 29th, 2023 بایگانی‌ها

5 / 0

Easy Candlestick Patterns دانلود و معرفی اکسپرت

معرفی و دانلود اکسپرت کاربردی Easy Candlestick Patterns Easy Candlestick Patterns الگوهای کندل استیک را تشخیص می دهد، بسته به آخرین الگوی کندل استیک معاملات را باز می کند و همچنین نام آن را (زمانی که گزینه ShowInfo فعال است) مستقیماً روی نمودار جفت ارز نمایش می دهد. معرفی اکسپرت کاربردی Easy Candlestick Patterns همچنین […]

0 ادامه مقاله

می 6th, 2024 بایگانی‌ها

5 / 0

No Nonsense Tester Demo اکسپرت MT5

معرفی و دانلود اکسپرت کاربردی No Nonsense Tester Demo No Nonsense Tester Demo برای آزمایش و تجارت بیدرنگ الگوریتم NNFX شما. این یک نسخه آزمایشی است، نسخه کامل را از mt5.karelnagel.com دریافت کنید. معرفی اکسپرت کاربردی No Nonsense Tester Demo نسخه دمو – نسخه کامل کل الگوی NNFX را تست کنید – بله – بله […]

0 ادامه مقاله

آخرین مقالات

فوریه 27th, 2024 بایگانی‌ها

5 / 0

FT ADX Color Candles اندیکاتور MT5

معرفی و دانلود اندیکاتور کاربردی FT ADX Color Candles اندیکاتور کاربردی FT ADX Color Candles زمانی که نیاز دارید به طور همزمان به چندین مورد نگاه کنید، معامله می تواند بسیار خسته کننده باشد. اندیکاتور کاربردی FT ADX Color Candles قالب شمع ها، ساپورت ها، مقاومت ها، برنامه ها، اخبار و اندیکاتورها. هدف این ابزار […]

0 ادامه مقاله

می 8th, 2024 بایگانی‌ها

5 / 0

Real Spinning Top Candlestick اندیکاتور MT5

معرفی اندیکاتور کاربردی Real Spinning Top Candlestick اندیکاتور کاربردی Real Spinning Top Candlestick این نشانگر واقعی چرخش بالا یک نماد بال را در تعداد بالای چرخان موجود در نمودار ترسیم می کند. اندیکاتور Real Spinning Top Candlestick نشانگر واقعی چرخش بالا این صفحه چرخش دقیق روی نمودار را با نسبت ارتفاع بدنه و فیتیله متعادل […]

0 ادامه مقاله

می 8th, 2024 بایگانی‌ها

5 / 0

HighsAndLowsPro اندیکاتور MT5

معرفی و دانلود اندیکاتور کاربردی HighsAndLowsPro اندیکاتور HighsAndLowsPro برای متاتریدر 5، اوج و پایین های محلی را در نمودار نشان می دهد. بالا و پایین های ضعیف و قوی را تشخیص می دهد. اندیکاتور HighsAndLowsPro ضخامت خطوط و رنگ ها را می توان به صورت جداگانه تنظیم کرد. در تنظیمات پیش‌فرض، اوج و پایین‌های ضعیف […]

0 ادامه مقاله

بخش دانلود

فایل های که پسوند آنها rar یا zip یا 7z هست را چگونه باز کنم؟
توسط نرم افزار Winrar فایل را از حالت فشرده خارج کنید و بعد برای اجرا و یا نصب اقدام کنید. دانلود WINRAR

فایل های با فرمت mq4 و mq5 را چگونه اجرا کنم ؟
جهت اجرای این نوع فایل ها برای نسخه mq4 باید متاتریدر 4 را روی سیستم خود و برای نسخه mq5 متاتریدر 5 را روی سیستم عامل خود نصب داشته باشید . جهت راهنمایی کلیک کنید

به این مقاله امتیاز دهید.
رمز تمامی فایل ها :

دانلوذ اسکریپت خروجی لیست معاملات

کد فایل

//+------------------------------------------------------------------+
//|                             s_Closed Positions Export to CSV.mq5 |
//|                                                 Fernando Morales |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Fernando Morales"
#property link      "https://www.mql5.com"
#property version   "2.00"
#property script_show_inputs

input datetime 	deals_from 	= D'2010.10.01 00:00';		// Start Date
input datetime 	deals_to   	= D'2030.02.28 00:00';		// End date
input string 	FileName  	= "history_positions3.csv";	// File name to export data

void OnStart() 
{
	Print("##### START SCRIPT ####");
//---
	
	if ( deals_from >= deals_to ) 
	{
		Alert ("ERROR: The start date is earlier than the end date");
		return;
	}
	
	// Creating the file handle for the output file (WRITE)
	int file_handle = FileOpen(FileName,FILE_TXT|FILE_WRITE);
	string data = NULL;
	
	// Showing an error message if something goes wrong with creating the file handle
	if(file_handle == INVALID_HANDLE)
	{
		Alert("File open failed, error ",_LastError);
		return;
	}
	
	// Load into memory the trade history between the dates
	if ( HistorySelect( deals_from, deals_to ))
	{
		// Preparing the column anmes
		data  = "Position ID"			+"\t";
		data += "Type"					+"\t";
		data += "Symbol"				+"\t";
		data += "Volume"				+"\t";
		data += "Open Date/Time"		+"\t";
		data += "Open Price"			+"\t";
		data += "Close Date/Time"		+"\t";
		data += "Close Price"			+"\t";
		data += "TakeProfit"			+"\t";
		data += "StopLoss"				+"\t";
		data += "Position PnL"			+"\t";
		data += "Position PnL (points)"	+"\t";
		data += "Swap"					+"\t";
		data += "Swap (points)"			+"\t";
		data += "Commission"			+"\t";
		data += "Commission (points)"	+"\t";
		data += "Total PnL"				+"\t";
		data += "Total PnL (points)"	+"\t";
		data += "MagicNumber"			+"\t";
		data += "Comment"				+"\t";
		data += "Deal in ID"			+"\t";
		data += "Deal out ID"			+"\t";
		
		// Writting the column name in the file
		FileWrite(file_handle, data );

		ulong deal_in_ticket=-1;
		bool IsDupe;

		// Loading all Deals in memory
		int deals_total = HistoryDealsTotal();
		
		// Define the array to store positions ID
		ulong arr_Positions[];
		ArrayResize( arr_Positions, deals_total, true );
		
		// We loop through all deals loaded in memory to stored the POSITION_IDENTIFIER into an array for later use
		for( int i = 0; i < deals_total; i++ )
			
			// For each DEAL load in memory we filter for the DEAL_IN only, then we will store the POSITION_IDENTIFIER
			if( ( deal_in_ticket = HistoryDealGetTicket( i )) > 0 && HistoryDealGetInteger(deal_in_ticket, DEAL_ENTRY) == DEAL_ENTRY_IN ) 
	        {				
				// Obtain the POSITION IDENTIFIER
				ulong  _posID=HistoryDealGetInteger(deal_in_ticket,DEAL_POSITION_ID);
				
				IsDupe = false;
				
				// We loop through already collected data seeking for duplicates
				// If a duplicate is found the loop is stoped
				for ( int j = i; j >= 0; j-- )
				{
					if ( arr_Positions[j] == _posID ) 
					{
						IsDupe = true;	// a duplicate was found
						break;
					}
				}

				if ( IsDupe ) continue;  // If a duplicate was found, the loop jumps to next iteration
				
				arr_Positions[i] = _posID;  // If no duplicate found, we store the _posID into the array
			}
			
		int _history_deals_by_pos = -1;
		int _history_order_by_pos = -1;
		int size = ArraySize(arr_Positions);
		int cnt=0;
			
		// Now that we got all POSITION IDENTIFIER in our array, we will process them
		for( int i = 0; i < size ; i++ )
		{
			// Declaring all used variables
			long _direction=-1,_magic=-1;
			ulong _posID=0, deal_ticket, order_ticket;
			double open_price=-1, close_price=-1, deal_volume=0, _tp=-1, _sl=-1, _profit=0, _swap=0, _commission=0;
			string _comment=NULL, _symbol=NULL,_deal_in_ID=NULL, _deal_out_ID=NULL,close_time=NULL, open_time=NULL;

			// Loading DEALs and ORDERS belonging to one POSITION
			if ( HistorySelectByPosition(arr_Positions[i]) )
			{
				// If there is not POS_ID move to next iteration
				if ( arr_Positions[i] == 0 ) continue;
				
				cnt++;

				// Counting the DEALS and ORDERS with the same POS_ID
				_history_deals_by_pos = HistoryDealsTotal();
				_history_order_by_pos = HistoryOrdersTotal();				

				// Looping through each DEAL
				for( int j = 0; j <= _history_deals_by_pos; j++ )
				{
					// Get the DEAl ticket for this round
					deal_ticket=HistoryDealGetTicket( j );
					
					// If there is no ticket we move to next iteration
					if ( deal_ticket == 0 ) continue;
					
					// Collecting information of if the DEAL is a DEAL_OUT or DEAL_INOUT or DEAL_OUT_BY
					if ( HistoryDealGetInteger(deal_ticket, DEAL_ENTRY) != DEAL_ENTRY_IN ) 
					{
						close_time	= TimeToString( HistoryDealGetInteger(deal_ticket, DEAL_TIME),TIME_DATE)+" "+TimeToString( HistoryDealGetInteger(deal_ticket, DEAL_TIME),TIME_SECONDS);
						close_price	= HistoryDealGetDouble (deal_ticket, DEAL_PRICE);
						deal_volume	+= HistoryDealGetDouble (deal_ticket, DEAL_VOLUME);
						_deal_out_ID+= IntegerToString( deal_ticket)+";";
					}
					
					// Collecting information of if the DEAL is DEAL_IN
					if ( HistoryDealGetInteger(deal_ticket, DEAL_ENTRY)== DEAL_ENTRY_IN  ) 
					{
						_direction	= HistoryDealGetInteger(deal_ticket, DEAL_TYPE);
						open_time	= TimeToString( HistoryDealGetInteger(deal_ticket, DEAL_TIME),TIME_DATE)+" "+TimeToString( HistoryDealGetInteger(deal_ticket, DEAL_TIME),TIME_SECONDS);
						open_price	= HistoryDealGetDouble (deal_ticket, DEAL_PRICE);
						_deal_in_ID+= IntegerToString( deal_ticket)+";";
					}
					
					_posID		 = HistoryDealGetInteger(deal_ticket, DEAL_POSITION_ID);
					_magic		 = HistoryDealGetInteger(deal_ticket, DEAL_MAGIC);
					_symbol		 = HistoryDealGetString (deal_ticket, DEAL_SYMBOL);
					_commission	+= HistoryDealGetDouble (deal_ticket, DEAL_COMMISSION);
					_swap		+= HistoryDealGetDouble (deal_ticket, DEAL_SWAP);
					_profit		+= HistoryDealGetDouble (deal_ticket, DEAL_PROFIT);
					_comment	+= HistoryDealGetString (deal_ticket, DEAL_COMMENT)+"/";
				}
	
				// Looping through all the ORDERS
				for( int j = _history_order_by_pos; j > 0; j-- )
				{
					order_ticket = HistoryOrderGetTicket( j );
					if ( order_ticket == 0 ) continue;
					
					HistoryOrderGetDouble( order_ticket, ORDER_TP, _tp );
					HistoryOrderGetDouble( order_ticket, ORDER_SL, _sl );
				}
	
				// Replacing all the dots (.) with dashes (-) for Excel to recognise the date format automatically
				StringReplace( close_time, ".", "-");
				StringReplace( open_time,  ".", "-");
	
				double tick_value_profit 	= SymbolInfoDouble (_symbol, SYMBOL_TRADE_TICK_VALUE_PROFIT);
				double tick_value_loss 		= SymbolInfoDouble (_symbol, SYMBOL_TRADE_TICK_VALUE_LOSS);
				double tick_size  			= SymbolInfoDouble (_symbol, SYMBOL_TRADE_TICK_SIZE);
				double points	  			= SymbolInfoDouble (_symbol, SYMBOL_POINT);
				int    decimals		   = (int)SymbolInfoInteger(_symbol, SYMBOL_DIGITS);
	
				double total_profit 		= _profit+_swap+_commission;
				double tick_value = ( _profit < 0 )? tick_value_loss : tick_value_profit;
												
				// Preparing the data
				data  = IntegerToString(_posID)+"\t";
				data += GetDealTypeDescr(int(_direction))+"\t";
				data += _symbol+"\t";
				data += DoubleToString(deal_volume,decimals)+"\t";
				data += open_time+"\t";
				data += DoubleToString(open_price,decimals)+"\t";
				data += close_time+"\t";
				data += DoubleToString(close_price,decimals)+"\t";
				data += DoubleToString(_tp,decimals)+"\t";
				data += DoubleToString(_sl,decimals)+"\t";
				data += DoubleToString(_profit,2)+"\t";
				data += DoubleToString(_profit / ( deal_volume / tick_size * tick_value ) / points, 2 )+"\t";
				data += DoubleToString(_swap,2)+"\t";
				data += DoubleToString(_swap / ( deal_volume / tick_size * tick_value ) / points, 2 )+"\t";
				data += DoubleToString(_commission,2)+"\t";
				data += DoubleToString(_commission / ( deal_volume / tick_size * tick_value ) / points, 2 )+"\t";
				data += DoubleToString(total_profit,2)+"\t";
				data += DoubleToString(total_profit / ( deal_volume / tick_size * tick_value ) / points, 2 )+"\t";
				data += IntegerToString(_magic)+"\t";
				data += _comment+"\t";
				data += _deal_in_ID+"\t";
				data += _deal_out_ID+"\t";
											
				// Writting data to the file
				FileWrite( file_handle,data);
								
			}//end HistorySelectByPosition		
		}//end for (i)
	printf("I found %d positions in hisotry", cnt );
	}//end if select history
			
	// Closing file
	FileClose(file_handle);

//---  
	Print("##### END SCRIPT ####");
}

string GetDealTypeDescr(int deal_type)
{
	string descr;

	switch(deal_type)
	{
		case DEAL_TYPE_BALANCE:                  return ("balance");
		case DEAL_TYPE_CREDIT:                   return ("credit");
		case DEAL_TYPE_CHARGE:                   return ("charge");
		case DEAL_TYPE_CORRECTION:               return ("correction");
		case DEAL_TYPE_BUY:                      return ("buy");
		case DEAL_TYPE_SELL:                     return ("sell");
		case DEAL_TYPE_BONUS:                    return ("bonus");
		case DEAL_TYPE_COMMISSION:               return ("additional commission");
		case DEAL_TYPE_COMMISSION_DAILY:         return ("daily commission");
		case DEAL_TYPE_COMMISSION_MONTHLY:       return ("monthly commision");
		case DEAL_TYPE_COMMISSION_AGENT_DAILY:   return ("Daily agent commission");
		case DEAL_TYPE_COMMISSION_AGENT_MONTHLY: return ("Monthly agent commission");
		case DEAL_TYPE_INTEREST:                 return ("interest rate");
		case DEAL_TYPE_BUY_CANCELED:             return ("buy canceled");
		case DEAL_TYPE_SELL_CANCELED:            return ("sell canceled");
	}
	
	return(descr);
}

ویدیو های آموزشی فارسی

کتاب های آموزش فارکس

کتاب های آموزش بورس

مطالعه مقالات بازار بورس

مطالعه مقالات بازار فارکس

مطالعه مقالات ارز های دیجیتال

معرفی بروکر های بازار فارکس

استراتژی ها و ابزار های معاملاتی

فرهنگ تخصصی لغات

ویدیو های آموزشی انگلیسی

دانلود کتاب ها و مقالات انگلیسی

دانلود اکسپرت های معاملاتی

دانلود اندیکاتور های کاربردی

دانلود اسکریپت های کاربردی

دانلود اسکریپت خروجی لیست معاملات به صورت اکسل CSV

برچسب‌ها :

مقالات مرتبط

Amka Ccf دانلود و معرفی اندیکاتور

Easy Candlestick Patterns دانلود و معرفی اکسپرت

No Nonsense Tester Demo اکسپرت MT5

آخرین مقالات

FT ADX Color Candles اندیکاتور MT5

Real Spinning Top Candlestick اندیکاتور MT5

HighsAndLowsPro اندیکاتور MT5

بخش دانلود

کد فایل